#1

Hejsan!

Jag byter upplösning på min skärm lite då och då vilket ofta gör att alla mina flikar som jag har nertill på skärmen försvinner.

Idag bestämde jag mig för att fixa ett Applescript som återställer dem som jag vill ha det och det hittar du nedan. Mitt manus sparar dessutom undan de flikar som du redan hade innan manuset kördes och gör flikar av dem med efter att din standarduppsättning av flikar är gjord.

I manuset finns mycket kommentarer så du kan säkert anpassa det till dina önskemål.

Jo, jag har bara testat i Mac OS 9.

Enjoy!

/Ola

Citat:

code:<pre style="font-size:x-small; font-family: monospace;">(*
GÖR FLIKAR AV VISSA MAPPAR
----------------------------------------------------------------
Av: Intelligent Mammals HB, 2002-10-05
[email protected]
http://www.intelligentmammals.se/

Detta script gör flickar av vissa mappar som jag vill ha nertill på skärmen

Först gör jag en lista av vilka mappar jag vill ha som flikar i en variabel
(Tryck alt-retur för att göra en radbrytning i ett Applescript
som syntax-kontrollen kommer att igorera).
Skriv sökvägen till alla dina mappar här:
*)

set folderitemsforpops to {¬
"Macintosh HD:_Alias_", ¬
"Macintosh HD:_Utvecklingsalias", ¬
"Macintosh HD:Data:Applescript", ¬
"Macintosh HD:Data", ¬
"Macintosh HD:Data 2:Intelligent Mammals"}

(*
Om det redan finns några flikar så sparar vi undan dem i denna variabel
längre ner i scriptet
*)
set currenttabs to {} as list -- En tom lista

tell application "Finder"
activate

(*
Nästa steg är stänga alla öppna fönster och ta bort de mappar som redan är flikar.
Kommandot "windows" returnerar alla öppna fönster och alla flikar.
*)
set allwindows to windows
repeat with awindow in allwindows
(*
Här kollas om fönstret vi jobbar med nu är en flik, i så fall ställer vi in
att det inte är det.
*)
if popup of awindow is true then
set popup of awindow to false

(*
Här sparar vi undan de flikar som redan finns.
Genom att använda "container of" och "as text" så får vi
en textsträng som ser exakt likadan ut som de vi redan har
skrivit ovan.
*)
set folderpath to container of awindow as text as list

(*
Om foldern ifråga redan finns i listan så behöver vi inte
lägga till den.
*)
if folderpath is not in folderitemsforpops then
set currenttabs to currenttabs & folderpath
end if

end if
close awindow
end repeat

(*
Nu sätter vi ihop listan på flikar vi alltid vill ha med de flikar som
vi redan hade.
*)
set folderitemsforpops to folderitemsforpops & currenttabs

(*
Nu görs flikar av de mappar som skrivits in ovan
*)
repeat with pops in folderitemsforpops
open folder (pops as alias)
set popup of window 1 to true
set pulled open of window 1 to false
end repeat
end tell</pre>