Apple Mail: Applescript för att svara alla markerade

Har bytt från Eudora till Mail och upptäcker nya begränsningar i Mail var och varannan dag. En irriterande detalj är att man inte kan svara på flera markerade mail samtidigt. Nå, jag hittade snabbt ett bra AppleScript som löser problemet och tänkte dela det här.

set thesenders to {}
set thesenderstext to ""
tell application "Mail"
    set themessage to the selection
    repeat with i from 1 to the number of items in themessage
        set thesender to (extract address from (the sender of (item i of themessage)))
        if thesenders does not contain thesender then
            set thesenders to thesenders & {thesender}
        end if
        set the was replied to of (item i of the themessage) to true
    end repeat
    set AppleScript's text item delimiters to ", "
    set thesenderstext to thesenders as text
    set AppleScript's text item delimiters to ""
    set newMessage to make new outgoing message
    tell newMessage
        set visible to true
        make new bcc recipient with properties {address:thesenderstext}
    end tell
    set toAddress to email addresses of item 1 of accounts as text
    tell newMessage
        make new to recipient with properties {address:toAddress}
    end tell
    activate
end tell

Källa

Scriptet skapar ett tomt mail och lägger dig själv i till-fältet och övriga mottagare i dold kopia.

Upptäckte nyligen att scriptet inte lirade riktigt med Lion, så jag tog bort en rad. Nu ser det ut så här:

set thesenders to {}set thesenderstext to ""
tell application "Mail"
    set themessage to the selection
    repeat with i from 1 to the number of items in themessage
        set thesender to (extract address from (the sender of (item i of themessage)))
        if thesenders does not contain thesender then
            set thesenders to thesenders & {thesender}
        end if
    end repeat
    set AppleScript's text item delimiters to ", "
    set thesenderstext to thesenders as rich text
    set AppleScript's text item delimiters to ""
    set newMessage to make new outgoing message
    tell newMessage
        set visible to true
        make new bcc recipient with properties {address:thesenderstext}
    end tell
    set toAddress to email addresses of item 1 of accounts as rich text
    tell newMessage
        make new to recipient with properties {address:toAddress}
    end tell
    activate
end tell

Jag gjorde så här, men det finns kanske smidigare sätt att få tillgång till scriptet inifrån Mail.

1) Kopiera ovanstående kod
2) Öppna programmet AppleScript-redigerare
3) Klistra in koden, spara som program, t.ex. med namnet Svara alla markerade
4) Jag har lagt till programmet i Dock (bredvid Mail-ikonen).
5) Markera de brev du vill svara på i Mail, klicka sedan på programmet