Kod: Läsa och sätta file och creator type

Här är ett AppleScript som hanterar creator type och file type på filer. Man kan visa och om man vill ändra dessa värden. Tråden handlar INTE om vilka alternativ det finns (det finns massor av program som gör detta och mycket mer).

Se det som vi gjorde när vi skrev det idag, som en studie i AppleScript. Användbart dock.

-- © 2006 Wire
-- Senast ändrat 2006-12-06

-- Scriptet visar och om man vill ändrar på file- och creator type

-- OBS 1
-- Eftersom vi inte behöver "återvinna" resultatet av display dialog
-- kan vi skriva över variabeln dialog_result vid varje ny display dialog

-- OBS 2
-- Vi kontrollerar inte den nya värdena för file- och creator type

--OBS 3
-- Ingen error-hanlder

-- OBS 4
-- Även om man kan droppa flera filer hanterar vi bara den första i listan.


on open file_alias_list -- ger en lista med droppade filer {alias "Macintosh HD:Users:admin......."}
	
	-- Tar reda på nuvarande creator- och file type
	tell application "Finder"
		set creator_type to creator type of item 1 in file_alias_list
		set file_type to file type of item 1 in file_alias_list
		set filnamn to name of item 1 in file_alias_list
	end tell
	
	-- Variabeln dialog_result nedan är  av typen record. T.ex. {button returned:"Ja"}
	set dialog_result to display dialog "Fil: " & filnamn & return & "Nuvarande creator typ: " & creator_type & return & "Nuvarande file type: " & file_type & return & return & "Vill du ändra dessa värden?" buttons {"Ja", "Nej"} default button "Nej" with icon 1
	
	if button returned in dialog_result is "Nej" then return quit {}
	
	
	-- ##### Hantering av creator type #####
	-- Variabeln dialog_result nedan är  av typen record. T.ex. {text returned:"CARO", button returned:"Ändra"}
	set dialog_result to display dialog "Ändra nuvarande creator typ" & return & "(msng är missing value)" default answer creator_type buttons {"Ändra", "Nej"} default button "Nej" with icon 1
	
	-- Vi vill ändra creator typ
	if button returned in dialog_result is "Ändra" then
		tell application "Finder"
			set creator type of item 1 in file_alias_list to (text returned in dialog_result)
		end tell
	end if
	-- #####
	
	
	-- ##### Hantering av file type #####
	set dialog_result to display dialog "Ändra nuvarande file typ" & return & "(msng är missing value)" default answer file_type buttons {"Ändra", "Nej"} default button "Nej" with icon 1
	
	-- Vi vill ändra file typ
	if button returned in dialog_result is "Ändra" then
		tell application "Finder"
			set file type of item 1 in file_alias_list to (text returned in dialog_result)
		end tell
	end if
	-- #####
	
	-- Avsluta
	quit {}
	
end open

-- Subrutiner
on quit {}
	continue quit
end quit