Sådärja, det var ju inte så knepigt!
Först - skapa en printer inställning i InD. T.ex en som printar till postscript fil, automatiskt sidformat, passmärken, skärmärken, utfall, alla fonter+bilder, Nivå 3, binär.
a) låter dig välja Indesign fil
b) låter dig välja utmapp
c) låter dig välja printer inställningar (av de förvalda som finns)
d) printar sidorna till din mapp med din inställning och döper dem till "filnamn_sidnummer.ps"
code:<pre style="font-size:x-small; font-family: monospace;">set theFile to (choose file with prompt "Välj InDesign filen!") as string
set theFolder to (choose folder with prompt "Var skall Postscript filerna sparas?") as string
tell application "Finder" to set theFileName to name of file theFile
tell application "InDesign 2.0.1"
activate
open theFile
set myDocument to active document
set NumberOfPage to pages per document of document preferences of myDocument
set thePrintPrefs to get name of printer styles
set theStyleToUse to (choose from list thePrintPrefs with prompt "Välj Inställning") as string
tell myDocument
tell print preferences
set active printer style to theStyleToUse
end tell
repeat with myPageCounter from 1 to NumberOfPage
set myPageNumber to (name of page myPageCounter of myDocument)
set myPSPathAndName to theFolder & theFileName & "_" & myPageNumber & ".ps"
tell print preferences
set page range to myPageCounter as string
set print file to myPSPathAndName
end tell
print without print dialog
end repeat
end tell
display dialog "Klart, stäng dokument och..." & return & " ¬
" with icon note buttons {"Stäng inte", "Spara inte", "Spara"} default button "Spara"
if button returned of the result is "Spara inte" then
close document 1 without saving
else if button returned of the result is "Spara" then
close document 1 with saving
end if
end tell</pre>
Kopiera, klistra in i Manusredigeraren, spara som ett kompilerat script och lägg det i din scripts folder (om du kör os x).
Detta är skrivet och fungerar på OS X 10.2.2 och InDesign 2.0.1.
Funkar säkert på andra configs också, men, man vet ju aldrig...
Lycka Till
Har du fundringar så kan du alltid maila.
/Mattias Jonsson
mattias.jonsson@framkom.se
Framkom Verksamhetsutveckling AB
